Cara Membuka File MS Word melalui Kotak Input Macro VBA Excel

Tip berikut ini akan menjelaskan cara menyusun kode macro dengan menggunakan kotak input (InputBox) untuk menanyakan nama file dokumen Word yang akan dibuka dari suatu folder tertentu di dalam komputer Anda.

Jika dokumen Word tersebut dinyatakan tidak ditemukan, maka Word tidak akan membuka di layar.

Langsung saja, berikut ini langkah-langkah yang bisa Anda ikuti:

1. Dari worksheet mana saja di workbook Excel Anda, silakan buka VBE dengan cara tekan Alt+F11.

2. Dari VBE buka menu Insert > Module.

3. Ketik kode macro berikut lalu tekan Enter:

Sub BukaFileWord()

4. Tepat di bawah kode di atas, tetapkan variabel untuk alamat folder misalnya A:

Dim A As String

5. Ketik alamat foldernya sesuai di dalam komputer Anda:

A = "C:\Alamat\File\Anda\"

6. Variabel B digunakan untuk perintah menampilkan InputBox:

Dim B As String

7. Variabel B dengan InputBox ini untuk menanyakan nama file Word yang akan dibuka dari alamat folder yang telah ditentukan. 

B = InputBox _
("Masukkan nama file dokumen yang akan dibuka" & Chr(10) & _
"dari alamat folder " & A & ":", _
"Apa nama file (dan ekstensinya) yang ingin Anda buka?", _
"namafile.docx")

8. Macro ditutup jika tidak ada yang dimasukkan atau tombol Cancel dipilih:

If B = "" Then Exit Sub

9. Untuk variabel C digunakan untuk mengkombinasikan alamat folder dan nama file:

Dim C As String
C = A & B

10. Untuk memeriksa apakah nama file dokumen Word benar-benar ada pada alamat folder, jika tidak ditemukan maka Macro ditutup dengan pemberitahuan bahwa nama file yang dimasukkan tidak ditemukan di komputer Anda melalui perintah kotak pesan (MsgBox):

If Dir(C) = "" Then
MsgBox "Nama file " & B & vbCrLf & _
"tidak ditemukan pada alamat folder" & vbCrLf & _
A & ".", _
vbExclamation, _
"Maaf, tidak ditemukan."
Exit Sub
End If

11. Di titik ini, file Word akan ditentukan apakah benar-benar ada di dalam folder. Tetapkan variabel misalnya D untuk aplikasi Word dan E untuk file dokumen Word:

Dim D As Object, E As Object

12. Anda tentunya masih ingat Cara Kedua dalam postingan sebelumnya Cara Membuka Aplikasi Office Lain dari Excel dengan Macro VBA, buat aplikasi Word:

Set D = CreateObject("Word.Application")

13. Pastikan aplikasi Word tampil di layar:

D.Visible = True

14. Buka file Word yang diminta menggunakan statement Set untuk variabel E:

Set E = D.Documents.Open(C)

15. Lepaskan memori penyimpanan untuk jenis variabel objek:

Set E = Nothing
Set D = Nothing

16. Silakan tes macro Anda yang mana kode lengkapnya sebagai berikut:

Sub BukaFileWord()
Dim A As String
A = "C:\Alamat\File\Anda\"
Dim B As String
B = InputBox _
("Masukkan nama file dokumen yang akan dibuka" & Chr(10) & _
"dari alamat folder " & A & ":", _
"Apa nama file (dan ekstensinya) yang ingin Anda buka?", _
"namafile.docx")
If B = "" Then Exit Sub
Dim C As String
C = A & B
If Dir(C) = "" Then
MsgBox "Nama file " & B & vbCrLf & _
"tidak ditemukan pada alamat folder" & vbCrLf & _
A & ".", _
vbExclamation, _
"Maaf, tidak ditemukan."
Exit Sub
End If
Dim D As Object, E As Object
Set D = CreateObject("Word.Application")
D.Visible = True
Set E = D.Documents.Open(C)
Set E = Nothing
Set D = Nothing
End Sub

Demikian cara membuka file dokumen Word dari Excel dengan cara menampilkan kotak input Macro VBA.

Silakan dicoba semoga bermanfaat.

Share :